/************************************************************
Below are SAS macros for calculating probabilities associated
with normal, binomial, t, chisquare and F distributions.
************************************************************/

%macro normprobs(mu,sigma2,a,b);
/******************************
Computes P(a<X<b), for X, 
a N(mu,sigma2) random variable
Note that sigma2 denotes sigma-squared.
******************************/
  title 'P(' &a '< X <' &b ') for X ~ N(' &mu ',' &sigma2 ')';
  data zresult;
   low_limit=&a;
   upp_limit=&b;
   mu=&mu;
   sigma=sqrt(&sigma2);
   result=CDF('NORMAL',&b,&mu,sigma)-CDF('NORMAL',&a,&mu,sigma);
  run;
  proc print noobs;run;
  title ' ';
%mend normprobs; 
/*
Sample calls: 
%normprobs(4,7,1,2);
%normprobs(4,7,-9999,2); (gets P(X<2))

*/
/******************************
******************************/

%macro binprobs(n,p,a,b);
/******************************
Computes P(a<X<=b), for X, a b(n,p) random variable.
To get P(X<=b) set a to a negative value.
******************************/
 %if &a ge 0 %then
 %do;
  title 'P(' &a '< X <=' &b ') for X ~ b(' &n ',' &p ')';
  data zresult;
   result=CDF('BINOMIAL',&b,&p,&n)-CDF('BINOMIAL',&a,&p,&n);
  run;
 %end;

%if &a lt 0 %then
 %do;
  title 'P( X <=' &b ') for X ~ b(' &n ',' &p ')';
  data zresult;
   result=CDF('BINOMIAL',&b,&p,&n);
  run;
 %end;
 proc print noobs;run;
 title ' ';
%mend binprobs;
***Sample call: %binprobs(150,.5,92,99);
***Sample call: %binprobs(150,.5,-1,99);

/******************************
******************************/

%macro tprobs(df,a,b);
/******************************
Computes P(a<X<b), for X, a 
t random variable with df 
degrees of freedom.
******************************/
  title 'P(' &a '< X <' &b ') for X ~ t(' &df ')';
  data zresult;
   low_limit=&a;
   upp_limit=&b;
   result=CDF('T',&b,&df)-CDF('T',&a,&df);
  run;
  proc print noobs;run;
  title ' ';
%mend tprobs; 
***Sample call: %tprobs(14,-1,1.788);

/******************************
******************************/

%macro chi2probs(df,a,b);
/******************************
Computes P(a<X<b), for X, a 
t random variable with df 
degrees of freedom.
******************************/
  title 'P(' &a '< X <' &b ') for X ~ chisquare(' &df ')';
  data zresult;
   low_limit=&a;
   upp_limit=&b;
   result=CDF('CHISQUARE',&b,&df)-CDF('CHISQUARE',&a,&df);
  run;
  proc print noobs;run;
  title ' ';
%mend chi2probs; 
***Sample call: %chi2probs(14,5,9.788);

/******************************
******************************/


%macro fprobs(df1,df2,a,b);
/******************************
Computes P(a<X<b), for X, a 
F random variable with df1 and df2 
degrees of freedom.
******************************/
  title 'P(' &a '< X <' &b ') for X ~ F(' &df1 ',' &df2 ')';
  data zresult;
   low_limit=&a;
   upp_limit=&b;
   result=CDF('F',&b,&df1,&df2)-CDF('F',&a,&df1,&df2);
  run;
  proc print noobs;run;
  title ' ';
%mend fprobs; 
***Sample call: %fprobs(8,24,5.69,9999);