      SUBROUTINE GP2DLF(PHI,DPX,DPY,DJ,X,Y,XI,ETA)
C
C GAUSS POINT 2 DIMENSIONAL LINEAR FINITE
C THIS PROGRAM WAS LAST UPDATED ON 10-27-83
C BY JOHN M. SULLIVAN, JR.   THE PROGRAM PERFORMS
C GAUSS QUADRATURE. LINEAR IN (XI) AND (ETA) DIRECTIONS
C
C      *----------*
C      !4        3!
C      !          !   NODE ORDERING IS CCW, FIRST NODE LOCATION
C      !1        2!     IS NOT CRITICAL.
C      *----------*
C
C STANDARD SERINDEPITY FINITE FORMULATIONS
C
      IMPLICIT REAL*8 (A-H,O-Z)
      DIMENSION PHI(4),DPX(4),DPY(4),X(4),Y(4)
      DIMENSION DPXI(4),DPE(4),DJA(4)
C
C BASIS FUNCTIONS FOR UNKNOWNS (I.E. TEMPERATURE)
C
      PHI(1) = 0.25*(1.-XI)*(1.-ETA)
      PHI(2) = 0.25*(1.+XI)*(1.-ETA)
      PHI(3) = 0.25*(1.+XI)*(1.+ETA)
      PHI(4) = 0.25*(1.-XI)*(1.+ETA)
C
C DERIVATIVES OF BASIS FUNCTIONS W.R.T. XI DIRECTION
C
      DPXI(1) = -0.25*(1.-ETA)
      DPXI(2) = 0.25*(1.-ETA)
      DPXI(3) = 0.25*(1+ETA)
      DPXI(4) = -0.25*(1.+ETA)
C
C DERIVATIVES OF BASIS FUNCTIONS W.R.T. ETA DIRECTION
C
      DPE(1) = -0.25*(1.-XI)
      DPE(2) = -0.25*(1.+XI)
      DPE(3) = 0.25*(1+XI)
      DPE(4) = 0.25*(1-XI)
C
C JACOBIAN
C
      DO 10 I=1,4
   10 DJA(I) = 0.0
      DO 11 I=1,4
      DJA(1)=X(I)*DPXI(I) + DJA(1)
      DJA(2)=Y(I)*DPXI(I) + DJA(2)
      DJA(3)=X(I)*DPE(I)  + DJA(3)
   11 DJA(4)=Y(I)*DPE(I)  + DJA(4)
      DJ = DJA(1)*DJA(4) - DJA(2)*DJA(3)
C
C DERIVATIVES W.R.T. X AND Y
C
      DDJ = 1./DJ
      DO 15 I=1,4
      DPX(I) = (DJA(4)*DPXI(I)-DJA(2)*DPE(I))*DDJ
   15 DPY(I) = (-DJA(3)*DPXI(I) + DJA(1)*DPE(I))*DDJ
      RETURN
      END
